home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / T-TPUG Old Monthly Disks / (c)t8.d64 / coil design.z (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  6KB  |  195 lines
  1. 100 CLR:PRINT"[147]"
  2. 110 REM"THIS IS A COIL DESIGN PROGRAM BY"
  3. 120 REM"HARRY L. ROSIER - K4LBF"
  4. 130 REM"FINAL DESIGN NOVEMBER 5, 1980."
  5. 140 REM"SPECIAL THANKS TO THE RADIO"
  6. 150 REM"AMATEUR'S HANDBOOK FOR THE"
  7. 160 REM"EQUATION AND WIRE TABLES"
  8. 170 PRINTTAB(12)"COIL DESIGN":PRINT:PRINT
  9. 180 PRINT"THIS PROGRAM IS SELF EXPLANATORY BUT "
  10. 190 PRINT"WOULD YOU LIKE A BRIEF DESCRIPTION?"
  11. 200 PRINT"PLEASE ANSWER (Y OR N)":INPUT D$
  12. 210 PRINT
  13. 220 IF D$="Y" THEN GOSUB1690
  14. 230 PRINT:PRINT
  15. 240 IF D$="N" THEN GOTO 280
  16. 250 PRINT"       TO CONTINUE, PRESS ANY KEY":FORI=1TO8:PRINT:NEXTI
  17. 260 GET A$:IF A$=""GOTO260
  18. 270 FOR I = 1 TO 100: NEXT I
  19. 280 PRINTTAB(15)"NOTES":PRINT:PRINT
  20. 290 PRINT"1. DESIGN OF THE COIL MUST MEET"
  21. 300 PRINT"   THE FOLLOWING CRITERIA:"
  22. 310 PRINT
  23. 320 PRINT"      75 MICROHENRIES MAX. INDUCTANCE"
  24. 330 PRINT"      .2 MICROHENRIES MIN. INDUCTANCE"
  25. 340 PRINT"       8 GAGE MAX. WIRE SIZE"
  26. 350 PRINT"      40 GAGE MIN. WIRE SIZE"
  27. 360 PRINT"     (FOR 1/4 INCH TUBING - USE SIZE 0)"
  28. 370 PRINT
  29. 380 PRINT"2. RESISTORS CAN BE USED AS COIL FORMS,"
  30. 390 PRINT"   AND MUST BE COMPOSITION TYPE HAVING"
  31. 400 PRINT"   THE FOLLOWING DIMENSIONS"
  32. 410 PRINT
  33. 420 PRINT"     1. 1/2 WATT - .14 X .38 INCHES"
  34. 430 PRINT"     2. 1   WATT - .22 X .58 INCHES"
  35. 440 PRINT"     3. 2   WATT - .30 X .70 INCHES"
  36. 450 PRINT"     (THESE ARE STANDARD RESISTOR SIZES)"
  37. 460 PRINT"3. OR,SELECT YOUR OWN DIAMETER FORM"
  38. 470 PRINT:PRINT"       TO CONTINUE PRESS ANY KEY"
  39. 480 GET A$: IF A$="" THEN480
  40. 490 FORI=1TO20:PRINT:NEXTI
  41. 500 PRINT"DO YOU WISH TO BEGIN WITH":PRINT
  42. 510 PRINT"1-INDUCTANCE IN MICROHENRIES, OR"
  43. 520 PRINT"2-INDUCTIVE REACTANCE"
  44. 530 PRINT
  45. 540 INPUT S:PRINT
  46. 550 IF S=1 THEN 660:IF S=2 THEN 570
  47. 560 IFS<1ORS>2THENPRINT"ANSWER 1 OR 2 PLEASE":GOTO540
  48. 570 PRINT"WHAT IS THE DESIRED INDUCTIVE REACTANCE IN OHMS":INPUTXL:PRINT
  49. 580 INPUT"WHAT FREQUENCY IN MEGAHERTZ";F:PRINT
  50. 590 L=XL/(2*3.14159*F)
  51. 600 L$=STR$(L)
  52. 610 PRINT"REQUIRED INDUCTANCE=";LEFT$(L$,5)
  53. 620 PRINT"MICROHENRIES"
  54. 630 IF L<.2 OR L>75  GOTO570
  55. 640 GOTO690
  56. 650 FOR X=1TO16:PRINT"":NEXT
  57. 660 PRINT"WHAT IS THE DESIRED COIL INDUCTANCE IN   MICROHENRIES":INPUTL:PRINT
  58. 670 IF L>75  THEN PRINT"75  MICRO-H MAX. PLEASE REENTER":GOTO660
  59. 680 IF L<.2 THEN PRINT"0.2 MICROHENRIES MIN.- PLEASE REENTER":GOTO660
  60. 690 PRINT"SELECT COIL FORM"
  61. 700 PRINT"   1-1/2 W RESISTOR"
  62. 710 PRINT"   2-1   W RESISTOR"
  63. 720 PRINT"   3-2   W RESISTOR"
  64. 730 PRINT"   4- OTHER FORM"
  65. 740 PRINT
  66. 750 INPUT A
  67. 760 IF A<1ORA>4 THEN750
  68. 770 IF A =1   THEN D=.140
  69. 780 IF A =2   THEN D=.220
  70. 790 IF A =3   THEN D=.300
  71. 800 IF A =4   THEN820
  72. 810 IF A =<3   THEN850
  73. 820 PRINT"WHAT IS THE DIAMETER OF THE"
  74. 830 PRINT"COIL IN INCHES?"
  75. 840 PRINT  : INPUT D
  76. 850 PRINT "WHAT GAGE ENAMELED WIRE IS TO BE USED  ":INPUT G
  77. 860 IF G=0 THEN W=.250
  78. 870 IF G=8  THEN W=.131
  79. 880 IF G=9  THEN W=.116
  80. 890 IF G=10 THEN W=.104
  81. 900 IF G=11 THEN W=.093
  82. 910 IF G=12 THEN W=.083
  83. 920 IF G=13 THEN W=.074
  84. 930 IF G=14 THEN W=.067
  85. 940 IF G=15 THEN W=.060
  86. 950 IF G=16 THEN W=.053
  87. 960 IF G=17 THEN W=.047
  88. 970 IF G=18 THEN W=.042
  89. 980 IF G=19 THEN W=.038
  90. 990 IF G=20 THEN W=.034
  91. 1000 IF G=21 THEN W=.030
  92. 1010 IF G=22 THEN W=.027
  93. 1020 IF G=23 THEN W=.024
  94. 1030 IF G=24 THEN W=.0216
  95. 1040 IF G=25 THEN W=.0193
  96. 1050 IF G=26 THEN W=.0172
  97. 1060 IF G=27 THEN W=.0154
  98. 1070 IF G=28 THEN W=.0138
  99. 1080 IF G=29 THEN W=.0122
  100. 1090 IF G=30 THEN W=.011
  101. 1100 IF G=31 THEN W=.0099
  102. 1110 IF G=32 THEN W=.00885
  103. 1120 IF G=33 THEN W=.0079
  104. 1130 IF G=34 THEN W=.0070
  105. 1140 IF G=35 THEN W=.0063
  106. 1150 IF G=36 THEN W=.0057
  107. 1160 IF G=37 THEN W=.0050
  108. 1170 IF G=38 THEN W=.0045
  109. 1180 IF G=39 THEN W=.0040
  110. 1190 IF G=40 THEN W=.0035
  111. 1200 IF G>40 THEN850
  112. 1210 N=((40*L*W)+SQR ((1600*W^2*L^2) +(72*D^2*L)))/(2*D^2)
  113. 1220 N1=((40*L*W)-SQR ((1600*W^2*L^2) +(72*D^2*L)))/(2*D^2)
  114. 1230 IF N>N1 THEN N2=N
  115. 1240 IF N<=N1 THEN N2=N1
  116. 1250 N2=(INT(N2*10))/10
  117. 1260 FOR X=1 TO 15:PRINT:NEXT
  118. 1270 PRINT"WIRE SIZE=";G;" GAGE"
  119. 1280 PRINT"COIL DIA.=";D;" INCHES"
  120. 1290 PRINT"NUMBER OF TURNS=";N2
  121. 1300 PRINT"COIL LENGTH=";(INT(N2*W*100))/100;" INCHES":PRINT
  122. 1310 R=INT(N2*W*100/D)/100
  123. 1320 IF A =1   THEN1480
  124. 1330 IF A =2   THEN1500
  125. 1340 IF A =3   THEN1520
  126. 1350 PRINT"THE LENGTH TO DIA. RATIO IS"
  127. 1360 PRINT R
  128. 1370 IF A=4 THEN GOSUB1540
  129. 1380 FOR X=1 TO 10:PRINT:NEXT
  130. 1390 PRINT "SELECT ANOTHER FORM AND/OR DIFFERENT "
  131. 1400 PRINT"SIZE WIRE?":PRINT
  132. 1410 INPUT"(Y OR N)";C$
  133. 1420 IF C$="Y" THEN690:PRINT
  134. 1430 PRINT "DESIGN ANOTHER COIL?(Y OR N)":INPUTB$
  135. 1440 IF B$="Y" THEN500
  136. 1450 PRINT:PRINT
  137. 1460 PRINT"O.K. GOOD LUCK WITH YOUR PROJECT!!"
  138. 1470 END
  139. 1480 IF N2*W>.385 THEN PRINT"COIL TOO LONG   FOR 1/2 W FORM":GOTO1390
  140. 1490 IF N2*W<=.385 GOTO1350
  141. 1500 IF N2*W>.525 THEN PRINT"COIL TOO LONG   FOR 1W FORM":GOTO1390
  142. 1510 IF N2*W<=.525 GOTO1350
  143. 1520 IF N2*W>.650 THEN PRINT"COIL TOO LONG    FOR 2W FORM":GOTO1390
  144. 1530 IF N2*W<=.650 GOTO1350
  145. 1540 PRINT"WOULD YOU LIKE TO SELECT THE LENGTH"
  146. 1550 INPUT"FOR A SPACE WOUND COIL (Y OR N)";Z$
  147. 1560 IF Z$="N" GOTO1450
  148. 1570 SL=(INT(N2*W*100))/100
  149. 1580 PRINT"THE LENGTH MUST BE GREATER THAN"; SL
  150. 1590 PRINT"INCHES,  NEW LENGTH?"
  151. 1600 INPUT NL
  152. 1610 N2=INT((SQR((L*(4.5*D+10*NL)/((D/2)^2))))* 100+.5)/100
  153. 1620 FOR X=1 TO 14:PRINT"":NEXT
  154. 1630 PRINT"WIRE SIZE=";G;" GAGE"
  155. 1640 PRINT"COIL DIA.=";D;" INCHES"
  156. 1650 PRINT"NUMBER OF TURNS=";N2
  157. 1660 PRINT"COIL LENGTH=";NL;"INCHES"
  158. 1670 RETURN
  159. 1680 END
  160. 1690 PRINTTAB(3)"THIS IS A COIL DESIGN PROGRAM BY"
  161. 1700 PRINT
  162. 1710 PRINTTAB(8)"HARRY L. ROSIER K4LBF" :PRINT:FORI=1TO2000:NEXT
  163. 1720 PRINT"THE PROGRAM IS TO BE USED TO DESIGN "
  164. 1730 PRINT"SINGLE LAYER SOLENOIDS ON STANDARD"
  165. 1740 PRINT"RESISTOR FORMS OR ON A FORM HAVING A "
  166. 1750 PRINT"DIAMETER OF YOUR CHOOSING."
  167. 1760 PRINT
  168. 1770 PRINT"THE INDUCTANCE FORMULA IS FROM THE"
  169. 1780 PRINT"RADIO AMATEUR'S HANDBOOK."
  170. 1790 PRINT
  171. 1800 PRINT"THIS FORMULA IS TRANSPOSED TO DETERMINE"
  172. 1810 PRINT"THE NUMBER OF TURNS REQUIRED, AND THE "
  173. 1820 PRINT"RESULTING QUADRATIC IS SOLVED USING THE"
  174. 1830 PRINT"CLASSICAL EQUATION."
  175. 1840 PRINT
  176. 1850 PRINT"YOU DECIDE THE SIZE OF COIL FORM, THE"
  177. 1860 PRINT"INDUCANCE, OR INDUCTIVE REACTANCE, AND"
  178. 1870 PRINT"THE THE WIRE SIZE -"
  179. 1880 PRINT
  180. 1890 PRINT"**** THE COMPUTER WILL DO THE REST! ****"
  181. 1900 PRINT:PRINT" TO CONTINUE PRESS ANY KEY":PRINT:PRINT
  182. 1910 GETZ$:IFZ$=""THEN1910
  183. 1920 PRINT"IF THE COIL SIZE/WIRE SIZE COMBINATION"
  184. 1930 PRINT"WON'T FIT ON THE RESISTOR FORM CHOSEN"
  185. 1940 PRINT"THEN THE COMPUTER WILL TELL YOU SO AND"
  186. 1950 PRINT"ASK FOR ANOTHER CHOICE."
  187. 1960 PRINT
  188. 1970 PRINT"IF YOU CHOOSE THE COIL DIAMETER, THEN"
  189. 1980 PRINT"THE LENGTH CAN BE WHATEVER IS NECESSARY.":PRINT
  190. 1990 PRINT"THE COMPUTER WILL ALSO TELL YOU THE"
  191. 2000 PRINT"LENGTH TO DIAMETER RATIO AND ASK IF YOU"
  192. 2010 PRINT"WOULD LIKE THE NUMBER OF TURNS FOR A"
  193. 2020 PRINT"SPACE WOUND COIL OF SPECIFIED LENGTH."
  194. 2030 RETURN
  195.